home *** CD-ROM | disk | FTP | other *** search
/ TPUG - Toronto PET Users Group / TPUG Users Group CD / TPUG Users Group CD.iso / C64 / B-Business / (c)b4.d64 / label maker.c (.txt) < prev    next >
Commodore BASIC  |  2007-02-04  |  16KB  |  603 lines
  1. 10 REM ***LABEL MAKER***
  2. 20 REM ///ORIGINAL PROGRAM WRITTEN BY S.P.TULK NBAGV-MADISON, OHIO-03/81
  3. 30 REM ///REVISED BY S.P. TULK NBAGU IN JUNE 1981 ///
  4. 40 REM
  5. 50 REM :::REVISED BY MICHAEL MOORE IN OCT. 1982:::
  6. 60 REM :::CONTRIBUTED BY MICHAEL MOORE TO APPLE CORPS OF DALLAS:::
  7. 70 REM
  8. 80 REM ---ADAPTED FOR COMMODORE 64 BY PHIL DEGELIA, DECATUR, TEXAS, 09/83---
  9. 120 PRINT CHR$(147):FOR I=1 TO 5:PRINT CHR$(17):NEXT I:PRINT SPC(7)
  10. 125 PRINT CHR$(18) " PRINTER MUST BE TURNED ON " CHR$(146)
  11. 130 FOR I=1 TO 1500:NEXT I
  12. 140 REM
  13. 145 REM :::::::LABEL INPUT MENU::::::::
  14. 148 REM
  15. 150 PRINT CHR$(147):PRINT:REM  CHR$(147) IS CLEAR/HOME
  16. 170 FOR I=1 TO 40:PRINT "*";:NEXT I:PRINT;
  17. 180 PRINT "*"SPC(38)"*";
  18. 190 PRINT "*     ***     LABEL MAKER    ***       *";
  19. 200 PRINT "*" SPC(38) "*";
  20. 210 FOR I=1 TO 40:PRINT "*";:NEXT I
  21. 212 PRINT CHR$(17) SPC(6) CHR$(17) "ORIGINAL PROGRAM WRITTEN BY:"
  22. 213 PRINT CHR$(17)SPC(13)"S. P. TULK"
  23. 214 PRINT CHR$(17)CHR$(17)SPC(7) "MODIFIED BY MICHAEL MOORE"
  24. 215 PRINT CHR$(17)CHR$(17)SPC(4)"ADAPTED FOR C-64 BY PHIL DEGELIA"
  25. 220 PRINT:PRINT "       PRINTER CODES DESIGNED FOR "
  26. 225 PRINT SPC(13) "GEMINI 10X/15 "
  27. 230 PRINT:PRINT
  28. 233 PRINT "   --PRESS " CHR$(18) "SHIFT" CHR$(146) " KEY TO CONTINUE.--"
  29. 235 WAIT 653,1
  30. 240 GOSUB 6300:E=1
  31. 245 REM   E IS EMPHASIZE ON/OFF FLAG=1 INDICATES OFF
  32. 250 PRINT CHR$(147)CHR$(17)CHR$(17)CHR$(17)
  33. 255 PRINT SPC(13) CHR$(18) " MAIN MENU " CHR$(146)
  34. 260 PRINT CHR$(17) SPC(15) "SELECTION"
  35. 330 PRINT:PRINT:PRINT "     [ 1 ] - - - NEW LABEL"
  36. 340 PRINT:PRINT "     [ 2 ] - - - YOUR LABEL"
  37. 350 PRINT:PRINT "     [ 3 ] - - - 10 MOST USED LABELS"
  38. 360 PRINT:PRINT "     [ 4 ] - - - SHORTENED DISK LABEL"
  39. 370 PRINT:PRINT "     [ 5 ] - - - FULL SIZE DISK LABEL"
  40. 380 PRINT:PRINT "     [ Q ] - - - < END >"
  41. 385 PRINT:PRINT:PRINT
  42. 390 PRINT "     [   ] .......YOUR CHOICE"
  43. 400 GET A1$:IF A1$="" THEN 400
  44. 450 IF A1$="1" THEN PRINT CHR$(147):S1=30:GOSUB 6020:GOSUB 11005:GOTO 1025
  45. 455 REM GET LABEL LINES-DISPLAY LABEL ON SCREEN-GOTO PRINT MENU ROUTINE
  46. 460 IF A1$="2" THEN PRINT CHR$(147):GOSUB 17010:PRINT CHR$(147):GOTO 1020
  47. 461 REM GET LABEL-GOTO PRINT MENU ROUTINE
  48. 470 IF A1$="3" THEN PRINT CHR$(147):GOTO 18010
  49. 471 REM GOTO MOST USED MENU ROUTINE
  50. 480 IF A1$="4" THEN S1=23:L=1:A=27:B=7:C=22:D=3:GOTO 4008
  51. 481 REM GOTO LABEL PRINT ROUTINE
  52. 485 IF A1$="5" THEN S1=29:L=1:A=33:B=10:C=28:D=0:GOTO 4008
  53. 486 REM GOTO LABEL PRINT ROUTINE
  54. 490 IF A1$="Q" THEN GOTO 25020
  55. 491 REM GOTO END ROUTINE
  56. 1000 REM
  57. 1005 REM ::::PRINT CHOICE::::
  58. 1008 REM
  59. 1020 GOSUB 11005:REM DISPLAY LABEL ON SCREEN
  60. 1022 REM CPL=CHARACTERS PER LINE
  61. 1025 PRINT:PRINT:PRINT SPC(14) CHR$(18)" PRINT MENU "CHR$(146)
  62. 1028 REM  CHR$(18) IS REVERSE ON --               CHR$(146) IS REVERSE OFF --
  63. 1030 PRINT SPC(15)"SELECTION"
  64. 1040 PRINT "   [ 1 ] - - - STANDARD 80 CPL"
  65. 1050 PRINT "   [ 2 ] - - - COMPRESSED 132 CPL"
  66. 1060 PRINT "   [ 3 ] - - - TRIPLE COLUMN LABELS-STD"
  67. 1065 PRINT "   [ 4 ] - - - DOUBLE WIDE/COMPR 66 CPL"
  68. 1070 PRINT "   [ 5 ] - - - DOUBLE WIDE 40 CPL"
  69. 1075 PRINT "   [ 6 ] - - - EMPHASIZED"
  70. 1080 PRINT "   [ 9 ] - - - RETURN TO MAIN MENU"
  71. 1085 GOSUB 10020:REM DISPLAY EMPHASIZE FLAG
  72. 1090 PRINT:PRINT "   [   ] ..... YOUR CHOICE"
  73. 1092 REM
  74. 1093 REM   ---- EMPHASIZED PRINT MODE DOES NOT COMBINE WITH COMPRESSED MODE---
  75. 1094 REM
  76. 1095 REM
  77. 1100 PRINT CHR$(19):FOR I=1 TO 11:PRINT CHR$(17):NEXT I:PRINT SPC(2):INPUT Y
  78. 1105 ON Y GOTO 1110,1120,1130,1140,1147,1149,1155,1155,1155
  79. 1110 PRINT CHR$(147)
  80. 1112 OPEN4,4,1:CMD4
  81. 1114 PRINT CHR$(18)
  82. 1116 PRINT#4:CLOSE4
  83. 1117 H=5:Q=18:GOSUB 11005:GOTO 12050
  84. 1118 REM DISPLAY LABEL ON SCREEN-GOTO LABEL PRINT ROUTINE
  85. 1119 REM  H=HORIZONTAL SPACING VARIABLE
  86. 1120 PRINT CHR$(147):Q=20
  87. 1121 OPEN4,4,1:CMD4
  88. 1122 PRINT CHR$(27)"F"
  89. 1123 PRINT CHR$(20)
  90. 1125 PRINT#4:CLOSE4
  91. 1126 REM  Q=VARIABLE TO TURN ON OR OFF COMPRESSED PRINT
  92. 1127 H=9:GOSUB 11005:GOTO 12050
  93. 1128 REM CHR$(27)"F" TURNS OFF EMPHASIZED PRINT
  94. 1129 REM CHR$(20) TURNS ON COMPRESSED PRINT - DISPLAY LABEL ON SCREEN
  95. 1130 H=5:GOSUB 2200:GOSUB 11005:GOTO 16010
  96. 1131 REM DISPLAY LABEL ON SCREEN-GOTO TRIPLE WIDE LABEL PRINT
  97. 1140 PRINT CHR$(147):OPEN4,4,1:CMD4:PRINT CHR$(27)"F":PRINT#4:CLOSE4
  98. 1141 OPEN4,4,1:CMD4:PRINT CHR$(20);:PRINT#4:CLOSE4
  99. 1142 H=4:GOSUB 11005:GOTO 14050:REM CHR$(27)"F" TURNS OFF EMPHASIZED PRINT
  100. 1144 REM CHR$(20) TURNS ON COMPRESSED PRINT
  101. 1145 REM DISPLAY LABEL ON SCREEN - GOTO LABEL PRINT ROUTINE
  102. 1147 H=3:S1=15:PRINT CHR$(147):GOSUB 11005:GOTO 14050
  103. 1148 REM GOTO LABEL PRINT ROUTINE
  104. 1149 PRINT CHR$(147)
  105. 1150 H=0:GOSUB 11005:PRINT CHR$(17)
  106. 1152 PRINT "    " CHR$(18) "          EMPHASIZE ON          " CHR$(146) "    "
  107. 1153 GOTO 1025
  108. 1155 GOTO 240:REM  RETURN TO MAIN MENU
  109. 2000 REM
  110. 2010 REM :::::INSTRUCTIONS:::::
  111. 2020 REM
  112. 2023 PRINT CHR$(147)
  113. 2025 PRINT:PRINT:PRINT "            " CHR$(18) " INSTRUCTIONS " CHR$(146)
  114. 2030 PRINT:PRINT:PRINT " PRINT WIDTH IS SET BY LINE LIMITER"
  115. 2040 PRINT " FOR 3 1/2 INCH LABELS."
  116. 2050 PRINT:PRINT " 5 LINES NORMAL OR 3 LINES BORDERED."
  117. 2070 PRINT:PRINT " DO NOT USE COMMAS OR COLONS."
  118. 2100 PRINT:PRINT " A RETURN WITH NO ENTRY WILL GIVE"
  119. 2110 PRINT " A BLANK LINE."
  120. 2120 PRINT:PRINT
  121. 2122 PRINT "   --PRESS " CHR$(18) "SHIFT" CHR$(146) " KEY TO CONTINUE.--"
  122. 2124 WAIT 653,1
  123. 2126 RETURN
  124. 2200 REM
  125. 2210 REM  ::TRIPLE COL. INSTRUCTIONS::
  126. 2220 REM
  127. 2225 PRINT CHR$(147)
  128. 2230 PRINT:PRINT:PRINT "    TRIPLE COLUMN LABEL INSTRUCTIONS"
  129. 2240 PRINT:PRINT:PRINT "  THE LENGTH OF TRIPLE COLUMN LABELS"
  130. 2250 PRINT "  MUST BE LESS THAN THE NORMAL WIDTH "
  131. 2255 PRINT "  LABEL."
  132. 2260 PRINT "  THE TRIPLE COLUMN LABELS ARE SET TO"
  133. 2265 PRINT "  PRINT A 17 CHARACTER LABEL WITH TWO"
  134. 2270 PRINT "  SPACES BETWEEN LABELS."
  135. 2280 PRINT "  THESE VARIABLES MAY BE CHANGED AT "
  136. 2290 PRINT "  PROGRAM LINES 16000 TO 17000."
  137. 2300 PRINT:PRINT "  IF YOU ENTERED A LABEL WITH "
  138. 2310 PRINT "  MORE THAN 17 CHARACTERS, YOU MAY "
  139. 2320 PRINT "  RETURN TO RE-ENTER THE LABEL."
  140. 2400 PRINT:PRINT
  141. 2410 PRINT "   DO YOU WANT TO RETURN TO THE"
  142. 2415 PRINT "   MAIN MENU? (CR='NO')"
  143. 2520 GET A6$:IF A6$="" THEN 2520
  144. 2530 IF A6$="Y" THEN 240
  145. 2540 IF A6$=CHR$(13) THEN RETURN
  146. 2550 IF A6$<>"Y" OR A6$<> CHR$(13) THEN 2520
  147. 4000 REM
  148. 4005 REM  ::::LABEL BORDER::::
  149. 4007 REM
  150. 4008 OPEN4,4,1:CMD4:PRINT CHR$(18):REM  TURN OFF COMPRESSED PRINT
  151. 4009 PRINT#4:CLOSE4:REM  TURN OFF PRINTER
  152. 4010 BR$="*":REM SET DEFAULT VALUE FOR LABEL BORDER
  153. 4011 V1$="001":REM  SETS INITIAL DISPLAY VALUE FOR VOLUME
  154. 4012 V2$=" VOL. ":REM  SET DEFAULT VALUE FOR TOP LINE
  155. 4013 A4$="6":V$="Y":A$="":B$="":C$=""
  156. 4014 Z$="  COM 64  ":REM  SETS INITIAL DISPLAY VALUE FOR BOTTOM BORDER
  157. 4015 GOSUB 4705:REM DISPLAY CURRENT LABEL
  158. 4031 PRINT:PRINT:PRINT "    WHAT CHARACTER DO YOU WANT TO USE"
  159. 4032 PRINT "    FOR THE BORDER? [   ]  DEFAULT = *"
  160. 4045 INPUT "";BR$
  161. 4050 IF LEN(BR$)=>2 THEN 4010
  162. 4055 PRINT CHR$(147)
  163. 4060 PRINT:PRINT:PRINT"  WOULD YOU LIKE A VOLUME NUMBER IN"
  164. 4061 PRINT "     THE TOP LINE OF THE BORDER ?":PRINT:PRINT
  165. 4070 PRINT "           [ Y ] - - - YES":PRINT
  166. 4080 PRINT "           [ N ] - - - NO":PRINT
  167. 4090 PRINT "           [   ] ..... YOUR CHOICE"
  168. 4091 GET V$:IF V$="" THEN 4091
  169. 4092 PRINT CHR$(147)
  170. 4110 IF V$="N" THEN 4191
  171. 4120 IF V$="Y" THEN PRINT CHR$(147):PRINT:PRINT
  172. 4121 PRINT "   ENTER YOUR VOLUME NUMBER (###)"
  173. 4122 PRINT "(MUST BE 3 CHARACTERS LONG)  [   ]";:GOTO 4140
  174. 4130 GOTO 4060
  175. 4140 INPUT "";V1$
  176. 4145 IF LEN(V1$)<>3 THEN 4060
  177. 4150 PRINT CHR$(147):PRINT:PRINT:PRINT "    ENTER REPLACEMENT FOR WORD 'VOL.'"
  178. 4151 PRINT "  IF DESIRED.   ( 4 CHARACTERS MAXIMUM)"
  179. 4152 PRINT TAB(8) "DEFAULT IS 'VOL.': [   ]"
  180. 4155 PRINT:PRINT:INPUT "";V2$:IF V2$="" THEN V2$="VOL."
  181. 4157 IF LEN(V2$) = 4 THEN V2$= " " +V2$+ " "
  182. 4159 IF LEN(V2$) = 3 THEN V2$ = " " + " " +V2$+ " "
  183. 4160 PRINT "4160":IF LEN(V2$) < 3 THEN 4060
  184. 4190 PRINT:PRINT:PRINT:
  185. 4191 PRINT CHR$(147)
  186. 4192 PRINT "     WHAT WOULD YOU LIKE IMPRINTED"
  187. 4194 PRINT "      AT THE BOTTOM OF THE BORDER?"
  188. 4200 PRINT:PRINT:PRINT "         [ 1 ] - - PET 2001":PRINT
  189. 4210 PRINT "         [ 2 ] - - CBM 8032 ":PRINT
  190. 4220 PRINT "         [ 3 ] - - CBM 4032 ":PRINT
  191. 4230 PRINT "         [ 4 ] - - CBM 8096 ":PRINT
  192. 4240 PRINT "         [ 5 ] - - VIC 20":PRINT
  193. 4245 PRINT "         [ 6 ] - - COM 64":PRINT
  194. 4250 PRINT "         [ 0 ] - - SOLID BORDER ":PRINT:PRINT
  195. 4260 PRINT "         [   ] ..... YOUR CHOICE";:PRINT
  196. 4262 GET A4$:IF A4$="" THEN 4262
  197. 4265 IF A4$ <"0" OR A4$> "8" THEN 4260
  198. 4270 IF A4$="1" THEN Z$= " PET 2001 "
  199. 4280 IF A4$="2" THEN Z$= " CBM 8032 "
  200. 4290 IF A4$="3" THEN Z$= " CBM 4032 "
  201. 4300 IF A4$="4" THEN Z$= " CBM 8096 "
  202. 4310 IF A4$="5" THEN Z$= "  VIC 20  "
  203. 4315 IF A4$="6" THEN Z$= "  COM 64  "
  204. 4320 IF A4$="0" THEN Z$= "**********"
  205. 4321 GOTO 4330
  206. 4325 L=1:GOSUB 4705:REM DISPLAY CURRENT LABEL
  207. 4330 PRINT CHR$(147):GOTO 12030:REM GOTO 80 CPL SETUP
  208. 4700 REM
  209. 4701 REM :::::DISK LABEL FORMAT:::::
  210. 4702 REM
  211. 4705 PRINT CHR$(147)
  212. 4710 H=4:REM SET VALUE FOR HORIZONTAL TAB DURING SCREEN DISPLAY
  213. 4720 IF V$="N" THEN V1$=BR$+BR$+BR$:REM FILL TOP BORDER WITH REQUIRED CHAR.
  214. 4723 LET J$=" "
  215. 4725 IF V$="N" THEN J$=BR$
  216. 4730 IF V$="N" THEN V2$=BR$+BR$+BR$+BR$+BR$+BR$
  217. 4760 PRINT TAB(H+D):FOR BR=1 TO B:PRINT BR$;:NEXT BR
  218. 4761 PRINT V2$;:PRINT V1$;:PRINT J$;:FOR BR=1 TO B:PRINT BR$;:NEXT BR
  219. 4762 PRINT CHR$(10)
  220. 4770 L=L+1:IF L=2 THEN L$=A$
  221. 4780 IF L=3 THEN L$=B$
  222. 4790 IF L=4 THEN L$=C$
  223. 4794 PRINT TAB(H+D)BR$;
  224. 4796 HT=INT((C-LEN(L$))/2)
  225. 4798 HA=HT+1
  226. 4800 T=HT+LEN(L$)+HA
  227. 4801 IF T>C THEN HA=HT
  228. 4803 PRINT SPC(HT)L$SPC(HA)BR$ CHR$(10)
  229. 4808 IF L<4 THEN 4770
  230. 4810 IF A4$="0" THEN Z$=BR$+BR$+BR$+BR$+BR$+BR$+BR$+BR$+BR$+BR$
  231. 4820 PRINT SPC(H+D);:FOR BR=1TO B:PRINT BR$;:NEXT BR
  232. 4830 PRINT Z$;:FOR BR=1TO B:PRINT BR$;:NEXT BR:PRINT CHR$(10) CHR$(10)
  233. 4845 L=1:REM RESET LINE COUNT FLAG
  234. 4850 RETURN
  235. 6000 REM
  236. 6005 REM  :::::INPUT LINES:::::
  237. 6010 REM
  238. 6020 PRINT CHR$(147)
  239. 6030 FOR I=1 TO 4:PRINT CHR$(17):NEXT I
  240. 6040 PRINT " INPUT LINE #1 "
  241. 6050 PRINT CHR$(19):FOR I=1 TO 4:PRINT CHR$(17):NEXTI:PRINT TAB(S1+1)"]"
  242. 6060 PRINT:PRINT SPC(5):INPUT "";A$
  243. 6070 PRINT CHR$(19):FOR I=1 TO 4:PRINT CHR$(17):NEXT I
  244. 6080 PRINT " INPUT LINE #2 "
  245. 6090 PRINT CHR$(19):FOR I=1 TO 4:PRINT CHR$(17):NEXTI:PRINT TAB(S1+1)"]"
  246. 6095 PRINT CHR$(19):FOR I=1 TO 6:PRINT CHR$(17):NEXT I
  247. 6100 PRINT SPC(5):INPUT "";B$
  248. 6110 PRINT CHR$(19):FOR I=1 TO 4:PRINT CHR$(17):NEXT I
  249. 6120 PRINT " INPUT LINE #3 "
  250. 6130 PRINT CHR$(19):FOR I=1 TO 4:PRINT CHR$(17):NEXTI:PRINT TAB(S1+1)"]"
  251. 6135 PRINT CHR$(19):FOR I=1 TO 7:PRINT CHR$(17):NEXT I
  252. 6140 PRINT SPC(5):INPUT "";C$
  253. 6150 PRINT CHR$(19):FOR I=1 TO 4:PRINT CHR$(17):NEXT I
  254. 6160 PRINT " INPUT LINE #4 "
  255. 6170 PRINT CHR$(19):FOR I=1 TO 4:PRINT CHR$(17):NEXTI:PRINT TAB(S1+1)"]"
  256. 6175 PRINT CHR$(19):FOR I=1 TO 8:PRINT CHR$(17):NEXT I
  257. 6180 PRINT SPC(5):INPUT "";E$
  258. 6190 PRINT CHR$(19):FOR I=1 TO 4:PRINT CHR$(17):NEXT I
  259. 6200 PRINT " INPUT LINE #5 "
  260. 6210 PRINT CHR$(19):FOR I=1 TO 4:PRINT CHR$(17):NEXTI:PRINT TAB(S1+1)"]"
  261. 6215 PRINT CHR$(19):FOR I=1 TO 9:PRINT CHR$(17):NEXT I
  262. 6220 PRINT SPC(5):INPUT "";F$
  263. 6230 RETURN
  264. 6300 REM
  265. 6310 REM  :::RESET LINE PRINT VALUES::
  266. 6320 REM
  267. 6330 A$=""
  268. 6340 B$=""
  269. 6350 C$=""
  270. 6360 E$=""
  271. 6370 F$=""
  272. 6380 RETURN
  273. 7000 REM
  274. 7005 REM  :::::HOW MANY?:::::
  275. 7010 REM
  276. 7020 PRINT:PRINT:PRINT "        HOW MANY LABELS ";
  277. 7040 INPUT X
  278. 7050 IF X=0 THEN GOTO 240:REM RETURN TO MAIN MENU
  279. 7060 RETURN
  280. 8000 REM
  281. 8005 REM  :::::STANDARD PRINT:::::
  282. 8010 REM
  283. 8020 IF L<>1 THEN GOTO 8040
  284. 8021 REM L=1 INDICATES THAT DISK LABELS ARE TO BE PRINTED
  285. 8030 FOR I=1 TO X:GOSUB 4720:NEXT I:REM PRINT DISK LABELS
  286. 8035 RETURN
  287. 8040 FOR I=1 TO X
  288. 8050 PRINT SPC(H) A$ CHR$(10):REM  CHR$(10) IS LINE FEED
  289. 8060 PRINT SPC(H) B$ CHR$(10)
  290. 8070 PRINT SPC(H) C$ CHR$(10)
  291. 8080 PRINT SPC(H) E$ CHR$(10)
  292. 8090 PRINT SPC(H) F$ CHR$(10)
  293. 8100 PRINT CHR$(10)
  294. 8110 NEXT I
  295. 8120 RETURN
  296. 9000 REM
  297. 9005 REM  :::::DOUBLE WIDE:::::
  298. 9010 REM
  299. 9015 REM  CHR$(14) REQUIRED ON EACH LINE TO TURN ON DOUBLE WIDE PRINT
  300. 9020 FOR I=1 TO X
  301. 9030 PRINT CHR$(14);
  302. 9040 PRINT SPC(H) A$ CHR$(10)
  303. 9050 PRINT CHR$(14);
  304. 9060 PRINT SPC(H) B$ CHR$(10)
  305. 9070 PRINT CHR$(14);
  306. 9080 PRINT SPC(H) C$ CHR$(10)
  307. 9090 PRINT CHR$(14);
  308. 9100 PRINT SPC(H) E$ CHR$(10)
  309. 9110 PRINT CHR$(14);
  310. 9120 PRINT SPC(H) F$ CHR$(10)
  311. 9130 PRINT CHR$(10)
  312. 9140 NEXT I
  313. 9150 PRINT#4:CLOSE4
  314. 9160 RETURN
  315. 10000 REM
  316. 10010 REM ::::SET UP EMPHASIZE::::
  317. 10015 REM
  318. 10020 IF E=0 THEN GOTO 10050
  319. 10030 IF E=1 THEN GOTO 10090
  320. 10040 RETURN
  321. 10050 OPEN4,4,1:CMD4:REM  PRINTER ON
  322. 10055 PRINT CHR$(27)"E"
  323. 10060 PRINT#4:CLOSE4
  324. 10065 REM CHR$(27)"E" TURNS ON EMPHASIZED PRINT
  325. 10080 E=1:RETURN
  326. 10090 OPEN4,4,1:CMD4:PRINT CHR$(27)"F":PRINT#4:CLOSE4
  327. 10091 REM CHR$(27)"F" TURNS OFF EMPHASIZED PRINT
  328. 10120 E=0:RETURN
  329. 11000 REM
  330. 11005 REM :SCREEN PRINT OF LABEL VALUES:
  331. 11010 REM
  332. 11020 PRINT CHR$(147)CHR$(17)CHR$(17):REM CHR$(147) IS CLR/HOME
  333. 11030 PRINT SPC(6)A$
  334. 11040 PRINT SPC(6)B$
  335. 11050 PRINT SPC(6)C$
  336. 11060 PRINT SPC(6)E$
  337. 11070 PRINT SPC(6)F$
  338. 11080 RETURN
  339. 12000 REM
  340. 12005 REM  ::::: 80 CPL SETUP :::::
  341. 12010 REM
  342. 12030 GOSUB 2000:REM  INSTRUCTIONS
  343. 12040 GOSUB 6020:REM  GET INPUT
  344. 12045 IF L=1 THEN GOSUB 4705:REM  DISPLAY DISK LABEL
  345. 12047 IF L<>1 THEN GOSUB 11020:REM DISPLAY REGULAR LABELS
  346. 12050 GOSUB 7020:REM  HOW MANY?
  347. 12060 OPEN4,4,1:CMD4
  348. 12064 REM  PRINTER ON
  349. 12070 GOSUB 8020:REM  PRINT LABELS
  350. 12079 PRINT CHR$(Q):REM  Q MAY TURN COMPRESSED PRINT ON OR OFF
  351. 12080 PRINT#4:CLOSE4
  352. 12081 REM  PRINTER OFF
  353. 12085 PRINT CHR$(147):IF L=1 THEN GOSUB 4705:IF L=1 THEN GOTO 12090
  354. 12088 GOSUB 11030
  355. 12090 PRINT:PRINT:PRINT "     MORE OF THE SAME LABEL ";:INPUT X$
  356. 12094 IF LEFT$(X$,1)="Y" THEN PRINT CHR$(147):GOTO 12047
  357. 12096 REM  PERFORM DISPLAY LABELS ON SCREEN--CHR$(147) IS CURSOR CLEAR/HOME
  358. 12100 IF LEFT$(X$,1)="N" THEN GOTO 12120
  359. 12110 GOTO 12085
  360. 12120 Q=18:L=0:GOSUB 6300:GOTO 240:REM  GOTO MAIN MENU
  361. 13000 REM
  362. 13005 REM  ::::: 132 CPL SETUP :::::
  363. 13010 REM
  364. 13020 OPEN4,4,1:CMD4
  365. 13021 PRINT CHR$(20)
  366. 13025 PRINT#4:CLOSE4
  367. 13029 REM  CHR$(20) TURNS ON COMPRESSED PRINT
  368. 13030 GOTO 12030:REM  GOTO PRINT SETUP
  369. 14000 REM
  370. 14005 REM  ::::: 40 CPL SETUP :::::
  371. 14010 REM
  372. 14030 GOSUB 2020:REM INSTRUCTIONS
  373. 14040 GOSUB 6020:REM  GET INPUT
  374. 14050 GOSUB 7020:REM  HOW MANY?
  375. 14060 OPEN4,4,1:CMD4
  376. 14070 GOSUB 9020:REM  PRINT LARGE
  377. 14090 PRINT CHR$(147):GOSUB 11020
  378. 14094 PRINT:PRINT "     MORE OF THE SAME LABEL ";:INPUT X$
  379. 14096 IF LEFT$(X$,1)="Y" THEN PRINT CHR$(147):GOSUB 11020:GOTO 14050
  380. 14098 REM  DISPLAY LABEL ON SCREEN
  381. 14100 OPEN4,4,1:CMD4
  382. 14110 PRINT CHR$(18)
  383. 14120 PRINT#4:CLOSE4
  384. 14200 GOSUB 6300:GOTO 240:REM  GOTO MAIN MENU
  385. 15000 REM
  386. 15005 REM  ::::: 66 CPL SETUP :::::
  387. 15010 REM
  388. 15020 OPEN4,4,1:CMD4
  389. 15030 PRINT CHR$(20);:
  390. 15031 REM  CHR$(20) TURNS ON COMPRESSED PRINT
  391. 15040 PRINT#4:CLOSE4
  392. 15080 GOTO 14030:REM  GOTO PRINT SETUP
  393. 16000 REM
  394. 16005 REM  :::::TRIPLE WIDE LABEL :::::
  395. 16010 REM
  396. 16020 GOSUB 11020:REM  DISPLAY LABEL
  397. 16035 PRINT:PRINT:PRINT SPC(5)"SPECIFY NUMBER OF ROWS OF 3 LABELS"
  398. 16040 GOSUB 7020:REM  HOW MANY LABEL ROWS?
  399. 16045 GOTO 16500
  400. 16046 REM
  401. 16047 REM  ::: CENTER JUSTIFIED :::
  402. 16048 REM
  403. 16050 OPEN4,4:CMD4
  404. 16055 R=17
  405. 16080 FOR I=1 TO X
  406. 16083 U=1
  407. 16100 U=U+1:IF U=2 THEN Y$=A$
  408. 16105 IF U=3 THEN Y$=B$
  409. 16110 IF U=4 THEN Y$=C$
  410. 16115 IF U=5 THEN Y$=E$
  411. 16120 IF U=6 THEN Y$=F$
  412. 16125 Q=LEN(Y$)
  413. 16130 P=INT((R-Q)/2)
  414. 16135 REM  P=SPACES VARIABLE
  415. 16140 PA=P+1
  416. 16145 PT=P+Q+PA
  417. 16150 IF PT>R THEN PA=P
  418. 16155 BT=3:REM  BT=SPACES BETWEEN TRIPLE COLUMN LABELS
  419. 16160 PRINT SPC(H+P) Y$;SPC(PA+BT+P);Y$;SPC(PA+BT+P);Y$
  420. 16165 IF U<6 THEN 16100
  421. 16170 U=1:REM RESET LINE COUNT FLAG
  422. 16175 PRINT
  423. 16180 NEXT
  424. 16360 PRINT#4:CLOSE4
  425. 16370 PRINT CHR$(147):GOSUB 11020:REM  DISPLAY LABEL
  426. 16380 PRINT:PRINT:PRINT "     MORE OF THE SAME LABEL ";:INPUT X$
  427. 16385 IF LEFT$(X$,1)="Y" THEN GOTO 16020
  428. 16390 PRINT CHR$(18) CHR$(27)"@":GOSUB 6300:GOTO 240:REM  GOTO MAIN MENU
  429. 16500 PRINT CHR$(147):PRINT:PRINT:PRINT
  430. 16510 PRINT "        DO YOU WANT THE LABELS:":PRINT:PRINT
  431. 16520 PRINT "        C - CENTER JUSTIFIED":PRINT
  432. 16530 PRINT "        L - LEFT JUSTIFIED":PRINT
  433. 16540 PRINT "        M - RETURN TO MAIN MENU"
  434. 16550 GET A7$:IF A7$="" THEN 16550
  435. 16560 IF A7$="C" THEN 16050
  436. 16570 IF A7$="L" THEN 16700
  437. 16580 IF A7$<>"C" AND A7$<>"L" THEN GOTO 240
  438. 16700 REM
  439. 16710 REM  :::: LEFT JUSTIFICATION :::
  440. 16720 REM
  441. 16730 OPEN4,4:CMD4
  442. 16740 R=17:FOR I=1 TO X:U=1:REM  R IS THE LINE LIMITER FOR ONE LABEL
  443. 16750 U=U+1:IF U=2 THEN Y$=A$
  444. 16760 IF U=3 THEN Y$=B$
  445. 16770 IF U=4 THEN Y$=C$
  446. 16780 IF U=5 THEN Y$=E$
  447. 16790 IF U=6 THEN Y$=F$
  448. 16800 Q=LEN(Y$):BT=3:REM  BT = SPACES BETWEEN THE LABELS
  449. 16810 P=INT(R-Q)
  450. 16820 REM  P=SPACES VARIABLE
  451. 16830 PRINT SPC(H) Y$;SPC(P+BT);Y$;SPC(P+BT);Y$
  452. 16840 IF U<6 THEN 16750
  453. 16850 U=1:REM  RESET LINE COUNT FLAG
  454. 16860 PRINT
  455. 16870 NEXT
  456. 16880 GOTO 16360
  457. 17000 REM
  458. 17005 REM  ::::: YOUR LABEL :::::
  459. 17010 REM
  460. 17020 A$="Y O U R   N A M E"
  461. 17030 B$="A D D R E S S "
  462. 17040 C$="CITY  STATE  ZIP"
  463. 17050 E$=""
  464. 17060 F$="ASSIGN AT LINE 17020"
  465. 17070 RETURN
  466. 18000 REM
  467. 18005 REM  ::::: 10 MOST USED :::::
  468. 18008 REM
  469. 18010 FOR I=1 TO 2:PRINT CHR$(17):NEXT I:PRINT SPC(3)
  470. 18015 PRINT "      10 MOST USED LABELS [146]":PRINT
  471. 18020 PRINT"             SELECT FROM:"
  472. 18030 PRINT:PRINT
  473. 18040 PRINT "    [ 1 ] - - - COMPUTE PUBLICATIONS"
  474. 18050 PRINT "    [ 2 ] - - - LABEL AT LINE18370"
  475. 18060 PRINT "    [ 3 ] - - - LABEL AT LINE18440"
  476. 18070 PRINT "    [ 4 ] - - - LABEL AT LINE18510"
  477. 18080 PRINT "    [ 5 ] - - - LABEL AT LINE18580"
  478. 18090 PRINT "    [ 6 ] - - - LABEL AT LINE18650"
  479. 18100 PRINT "    [ 7 ] - - - LABEL AT LINE18720"
  480. 18110 PRINT "    [ 8 ] - - - LABEL AT LINE18790"
  481. 18120 PRINT "    [ 9 ] - - - LABEL AT LINE18860"
  482. 18130 PRINT "    [ 0 ] - - - LABEL AT LINE18930"
  483. 18140 PRINT "    [ R ] - - - <RETURN TO MAIN MENU>"
  484. 18150 PRINT:PRINT:PRINT "    [   ] ..... YOUR CHOICE"
  485. 18165 GET A3$:IF A3$="" THEN 18165
  486. 18170 IF A3$="1" THEN GOSUB 18300:PRINT CHR$(147):GOTO 1020
  487. 18171 REM  PERFORM LABEL PICKUP - GOTO PRINT MENU
  488. 18180 IF A3$="2" THEN GOSUB 18370:PRINT CHR$(147):GOTO 1020
  489. 18190 IF A3$="3" THEN GOSUB 18440:PRINT CHR$(147):GOTO 1020
  490. 18200 IF A3$="4" THEN GOSUB 18510:PRINT CHR$(147):GOTO 1020
  491. 18210 IF A3$="5" THEN GOSUB 18580:PRINT CHR$(147):GOTO 1020
  492. 18220 IF A3$="6" THEN GOSUB 18650:PRINT CHR$(147):GOTO 1020
  493. 18230 IF A3$="7" THEN GOSUB 18720:PRINT CHR$(147):GOTO 1020
  494. 18240 IF A3$="8" THEN GOSUB 18790:PRINT CHR$(147):GOTO 1020
  495. 18250 IF A3$="9" THEN GOSUB 18860:PRINT CHR$(147):GOTO 1020
  496. 18260 IF A3$="0" THEN GOSUB 18930:PRINT CHR$(147):GOTO 1020
  497. 18270 IF A3$="R" THEN GOTO 240:REM  GOTO MAIN MENU
  498. 18290 REM  ::::: LABEL #1 :::::
  499. 18300 A$="COMPUTE PUBLICATIONS, INC."
  500. 18310 B$="P. O. BOX 5406"
  501. 18320 C$="GREENSBORO, NC  27403"
  502. 18330 E$="U.S.A."
  503. 18340 F$=""
  504. 18350 RETURN
  505. 18360 REM  ::::: LABEL #2 :::::
  506. 18370 A$="UNASSIGNED LINE 18370"
  507. 18380 B$=""
  508. 18390 C$=""
  509. 18400 E$=""
  510. 18410 F$=""
  511. 18420 RETURN
  512. 18430 REM  ::::: LABEL #3 :::::
  513. 18440 A$="UNASSIGNED LINE 18440"
  514. 18450 B$=""
  515. 18460 C$=""
  516. 18470 E$=""
  517. 18480 F$=""
  518. 18490 RETURN
  519. 18500 REM  ::::: LABEL #4 :::::
  520. 18510 A$="UNASSIGNED LINE 18510"
  521. 18520 B$=""
  522. 18530 C$=""
  523. 18540 E$=""
  524. 18550 F$=""
  525. 18560 RETURN
  526. 18570 REM  ::::: LABEL #5 :::::
  527. 18580 A$="UNASSIGNED LINE 18510"
  528. 18590 B$=""
  529. 18600 C$=""
  530. 18610 E$=""
  531. 18620 F$=""
  532. 18630 RETURN
  533. 18640 REM  ::::: LABEL #6 :::::
  534. 18650 A$="UNASSIGNED LINE 18650"
  535. 18660 B$=""
  536. 18670 C$=""
  537. 18680 E$=""
  538. 18690 F$=""
  539. 18700 RETURN
  540. 18710 REM  ::::: LABEL #7 :::::
  541. 18720 A$="UNASSIGNED LINE 18720"
  542. 18730 B$=""
  543. 18740 C$=""
  544. 18750 E$=""
  545. 18760 F$=""
  546. 18770 RETURN
  547. 18780 REM  ::::: LABEL #8 :::::
  548. 18790 A$="UNASSIGNED LINE 18790"
  549. 18800 B$=""
  550. 18810 C$=""
  551. 18820 E$=""
  552. 18830 F$=""
  553. 18840 RETURN
  554. 18850 REM  ::::: LABEL #9 :::::
  555. 18860 A$="UNASSIGNED LINE 18860"
  556. 18870 B$=""
  557. 18880 C$=""
  558. 18890 E$=""
  559. 18900 F$=""
  560. 18910 RETURN
  561. 18920 REM  ::::: LABEL #0 :::::
  562. 18930 A$="UNASSIGNED LINE 18860"
  563. 18940 B$=""
  564. 18950 C$=""
  565. 18960 E$=""
  566. 18970 F$=""
  567. 18980 RETURN
  568. 25000 REM
  569. 25010 REM  ::::: END :::::
  570. 25015 REM
  571. 25020 PRINT CHR$(147)
  572. 25030 PRINT CHR$(147):FOR I=1 TO 4:PRINT CHR$(17):NEXT I
  573. 25040 PRINT "          ********************"
  574. 25050 PRINT SPC(10)"*                  *"
  575. 25060 PRINT "          *     GOOD BYE     *"
  576. 25070 PRINT SPC(10)"*                  *"
  577. 25080 PRINT "          ********************"
  578. 25090 FOR I=1 TO 1000:NEXT I
  579. 25100 FOR I=1 TO 25:PRINT:NEXT I
  580. 25110 END
  581. 31000 REM
  582. 31010 REM  ::::: SUBROUTINE LIST :::::
  583. 31020 REM
  584. 31030 REM   100 SETUP/MAIN MENU
  585. 31040 REM  1000 PRINT MENU
  586. 31050 REM  2000 INSTRUCTIONS
  587. 31060 REM  4000 LABEL BORDER
  588. 31070 REM  5000 LINE LIMITER & INPUT LINES
  589. 31090 REM  7000 HOW MANY LABELS?
  590. 31100 REM  8000 STANDARD PRINT
  591. 31110 REM  9000 DOUBLE WIDE
  592. 31120 REM 10000 SETUP EMPHASIZED
  593. 31130 REM 11000 LABEL FOR SCREEN
  594. 31140 REM 12000 80 CPL SETUP
  595. 31150 REM 13000 132 CPL SETUP
  596. 31160 REM 14000 40 CPL SETUP
  597. 31170 REM 15000 66 CPL SETUP
  598. 31180 REM 16000 TRIPLE WIDE
  599. 31190 REM 17000 YOUR LABEL
  600. 31200 REM 18000 10 MOST USED
  601. 31210 REM 25000 END
  602. 31220 REM 31000 SUBROUTINE LIST
  603.